error with rs.exe utility

I'm getting some errors when I run rs.exe from command line with regard to Parameters, and was hoping I might get some help here. I'm somewhat new to RS. I'm running SQL 2000 and RS 2000 on a Windows 2003 Server.

Here is my script:
***********************************************************
' File: RunReport.rss
Dim format as string = "Excel"
Dim fileName as String = "C:\Export2.xls"
Dim reportPath as String = "/APSAgentCourseCompletionByUserGroup"

Public Sub Main()

' Prepare Render arguments
Dim historyID as string = Nothing
Dim deviceInfo as string = Nothing
Dim showHide as string = Nothing
Dim results() as Byte
Dim encoding as string
Dim mimeType as string = "ms-excel"
Dim warnings() AS Warning = Nothing
Dim reportHistoryParameters() As ParameterValue = Nothing
Dim streamIDs() as string = Nothing
rs.Credentials = System.Net.CredentialCache.DefaultCredentials

' Report Parameters
Dim parameters(5) As ParameterValue
parameters(0) = New ParameterValue()
parameters(0).Name = "User Group"
parameters(0).Value = "66179312-f341-4df7-a855-79c5b8abaf9f"
parameters(1) = New ParameterValue()
parameters(1).Name = "Start Date"
parameters(1).Value = "12/22/2006"
parameters(2) = New ParameterValue()
parameters(2).Name = "End Date"
parameters(2).Value = "2/17/2007"
parameters(3) = New ParameterValue()
parameters(3).Name = "Course Name"
parameters(3).Value = "AA2B1AA0-E78A-4F84-834F-8EAAB75BEBD3"
parameters(4) = New ParameterValue()
parameters(4).Name = "Status To Include"
parameters(4).Value = "0"
results = rs.Render(reportPath, format, _
Nothing, Nothing, parameters, _
Nothing, Nothing, encoding, mimeType, _
reportHistoryParameters, warnings, streamIDs)

' Open a file stream and write out the report
Dim stream As FileStream = File.OpenWrite(fileName)
stream.Write(results, 0, results.Length)
stream.Close()

End Sub

'End of script
***********************************************************

As you can see, right now I've got all 5 report parameters hard-coded.

Here is the command line that I'm using as well as the error that I receive:

rs.exe -i c:\RunReport.rss -s http://localhost/reportserver -t
Unhandled exception: The value of parameter 'Parameters' is not valid. Check the documentation for information about valid values.

Any insight that anyone can provide is greatly appreciated.

Thanks!

Ray

what...? no response to this yet? i'm desperately seeking samples for
how to use this rs.exe utility, and there's just not enough out there.

a comprehensive tutorial would be nice too actually; but thats just a dream at this point.
|||Yeah, i was really hoping that someone would respond to it as well, but luckily i stumbled upon my own solution. The error that I was receiving was because the array I initialized was incremented by too much. Instead of

Dim parameters(5) As ParameterValue

it should have been:

Dim parameters(4) As ParameterValue

Once I made that change the script was executing just fine!

Hope this helps you somewhat. Are you receiving other errors?